Components for Delphi and C++ Builder.

procedure TForm1.Button2Click(Sender: TObject);
var
  AllRecs: TRecordsListEh;
  i: Integer;
  NameIdx: Integer;
  Rec: TMemoryRecordEh;
begin
  AllRecs := MemTableEh1.RecordsView.MemTableData.RecordsList;
  NameIdx := MemTableEh1.RecordsView.MemTableData.DataStruct.FieldIndex('Name');
  for i := 0 to AllRecs.Count-1 do
  begin
    Rec := AllRecs.Rec[i];
    if VarToStr(Rec.Value[NameIdx, dvvValueEh]) = 'Canada' then
    begin
      Rec.Edit;
      Rec.DataValues['Capital', dvvValueEh] := '<<Ottawa>>';
      Rec.Post;
    end;
  end;
end;

function FindRecInRecordsList(RecList: TRecordsListEh; const KeyFields: string;
  const KeyValues: Variant; TryUseIndex: Boolean = True): TMemoryRecordEh;
var
  Fields: TList;
  I, RecIndex: Integer;
  MTIndex: TMTIndexEh;

  procedure GetFieldList(List: TList; const FieldNames: string);
  var
    Pos: Integer;
    Field: TMTDataFieldEh;
    Len: Integer;
  begin
    Len := FieldNames.Length;
    Pos := 1;
    while Pos <= Len do
    begin
      Field := RecList.DataStruct.FieldByName(ExtractFieldName(FieldNames, Pos));
      if Assigned(List) then List.Add(Field);
    end;
  end;

  function CompareRecValues(Rec: TMemoryRecordEh; const VarValues: Variant): Boolean;
  var
    I: Integer;
  begin
    if Fields.Count = 0 then
      Result := False
    else if Fields.Count = 1 then
      Result := VarEquals(Rec.Value[TMTDataFieldEh(Fields.First).Index, dvvValueEh], VarValues)
    else begin
      Result := True;
      for I := 0 to Fields.Count - 1 do
        Result := Result and VarEquals(Rec.Value[TMTDataFieldEh(Fields[I]).Index, dvvValueEh], VarValues[I]);
    end;
  end;

begin
  Result := nil;
  MTIndex := nil;
  Fields := TList.Create;
  try
    GetFieldList(Fields, KeyFields);

    if TryUseIndex then
      MTIndex := RecList.Indexes.GetIndexForFields(KeyFields);

    if MTIndex <> nil then
    begin
      if MTIndex.FindRecordIndexByKey(KeyValues, RecIndex) then
        Result := RecList[RecIndex]
    end else
    begin
      for I := 0 to RecList.Count-1 do
      begin
        if CompareRecValues(RecList.Rec[i], KeyValues) then
        begin
          Result := RecList.Rec[i];
          Break;
        end
      end;
    end;

  finally
    Fields.Free;
  end;
end;